home *** CD-ROM | disk | FTP | other *** search
/ Chip 2007 January, February, March & April / Chip-Cover-CD-2007-02.iso / Pakiet bezpieczenstwa / mini Pentoo LiveCD 2006.1 / mpentoo-2006.1.iso / livecd.squashfs / usr / bin / autoreconf-2.59 < prev    next >
Text File  |  2006-04-25  |  19KB  |  671 lines
  1. #! /usr/bin/perl -w
  2. # -*- perl -*-
  3. # Generated from autoreconf.in; do not edit by hand.
  4.  
  5. eval 'case $# in 0) exec /usr/bin/perl -S "$0";; *) exec /usr/bin/perl -S "$0" "$@";; esac'
  6.     if 0;
  7.  
  8. # autoreconf - install the GNU Build System in a directory tree
  9. # Copyright (C) 1994, 1999, 2000, 2001, 2002, 2003
  10. # Free Software Foundation, Inc.
  11.  
  12. # This program is free software; you can redistribute it and/or modify
  13. # it under the terms of the GNU General Public License as published by
  14. # the Free Software Foundation; either version 2, or (at your option)
  15. # any later version.
  16.  
  17. # This program is distributed in the hope that it will be useful,
  18. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20. # GNU General Public License for more details.
  21.  
  22. # You should have received a copy of the GNU General Public License
  23. # along with this program; if not, write to the Free Software
  24. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  25. # 02111-1307, USA.
  26.  
  27. # Written by David J. MacKenzie.
  28. # Extended and rewritten in Perl by Akim Demaille.
  29.  
  30. BEGIN
  31. {
  32.   my $datadir = $ENV{'autom4te_perllibdir'} || '/usr/share/autoconf';
  33.   unshift @INC, $datadir;
  34.  
  35.   # Override SHELL.  On DJGPP SHELL may not be set to a shell
  36.   # that can handle redirection and quote arguments correctly,
  37.   # e.g.: COMMAND.COM.  For DJGPP always use the shell that configure
  38.   # has detected.
  39.   $ENV{'SHELL'} = '/bin/sh' if ($^O eq 'dos');
  40. }
  41.  
  42. use Autom4te::ChannelDefs;
  43. use Autom4te::Channels;
  44. use Autom4te::Configure_ac;
  45. use Autom4te::FileUtils;
  46. use Autom4te::General;
  47. use Autom4te::XFile;
  48. # Do not use Cwd::chdir, since it might hang.
  49. use Cwd 'cwd';
  50. use strict;
  51.  
  52. ## ----------- ##
  53. ## Variables.  ##
  54. ## ----------- ##
  55.  
  56. # $HELP
  57. # -----
  58. $help = "Usage: $0 [OPTION] ... [CONFIGURE-AC or DIRECTORY] ...
  59.  
  60. Run `autoconf' (and `autoheader', `aclocal', `automake', `autopoint'
  61. (formerly `gettextize'), and `libtoolize' where appropriate)
  62. repeatedly to remake the GNU Build System files in the DIRECTORIES or
  63. the directory trees driven by CONFIGURE-AC (defaulting to `.').
  64.  
  65. By default, it only remakes those files that are older than their
  66. predecessors.  If you install new versions of the GNU Build System,
  67. running `autoreconf' remakes all of the files by giving it the
  68. `--force' option.
  69.  
  70. Operation modes:
  71.   -h, --help               print this help, then exit
  72.   -V, --version            print version number, then exit
  73.   -v, --verbose            verbosely report processing
  74.   -d, --debug              don't remove temporary files
  75.   -f, --force              consider all files obsolete
  76.   -i, --install            copy missing auxiliary files
  77.   -s, --symlink            with -i, install symbolic links instead of copies
  78.   -m, --make               when applicable, re-run ./configure && make
  79.   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY [syntax]
  80.  
  81. " . Autom4te::ChannelDefs::usage . "
  82.  
  83. The environment variable \`WARNINGS\' is honored.  Some subtools might
  84. support other warning types, using \`all' is encouraged.
  85.  
  86. Library directories:
  87.   -B, --prepend-include=DIR  prepend directory DIR to search path
  88.   -I, --include=DIR          append directory DIR to search path
  89.  
  90. The environment variables AUTOCONF, AUTOHEADER, AUTOMAKE, ACLOCAL,
  91. AUTOPOINT, LIBTOOLIZE are honored.
  92.  
  93. Report bugs to <bug-autoconf\@gnu.org>.
  94. ";
  95.  
  96. # $VERSION
  97. # --------
  98. $version = "autoreconf (GNU Autoconf) 2.59
  99. Written by David J. MacKenzie and Akim Demaille.
  100.  
  101. Copyright (C) 2003 Free Software Foundation, Inc.
  102. This is free software; see the source for copying conditions.  There is NO
  103. warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  104. ";
  105.  
  106. # Lib files.
  107. my $autoconf   = $ENV{'AUTOCONF'}   || '/usr/bin/autoconf-2.59';
  108. my $autoheader = $ENV{'AUTOHEADER'} || '/usr/bin/autoheader-2.59';
  109. my $automake   = $ENV{'AUTOMAKE'}   || 'automake';
  110. my $aclocal    = $ENV{'ACLOCAL'}    || 'aclocal';
  111. my $libtoolize = $ENV{'LIBTOOLIZE'} || 'libtoolize';
  112. my $autopoint  = $ENV{'AUTOPOINT'}  || 'autopoint';
  113.  
  114. # --install -- as --add-missing in other tools.
  115. my $install = 0;
  116. # symlink -- when --install, use symlinks instead.
  117. my $symlink = 0;
  118. # Does aclocal support --force?
  119. my $aclocal_supports_force = 0;
  120.  
  121. my @prepend_include;
  122. my @include;
  123.  
  124. # List of command line warning requests.
  125. my @warning;
  126.  
  127. # Rerun `./configure && make'?
  128. my $make = 0;
  129.  
  130. ## ---------- ##
  131. ## Routines.  ##
  132. ## ---------- ##
  133.  
  134.  
  135. # parse_args ()
  136. # -------------
  137. # Process any command line arguments.
  138. sub parse_args ()
  139. {
  140.   my $srcdir;
  141.  
  142.   getopt ("W|warnings=s"         => \@warning,
  143.       'I|include=s'          => \@include,
  144.       'B|prepend-include=s'     => \@prepend_include,
  145.       'i|install'            => \$install,
  146.       's|symlink'            => \$symlink,
  147.       'm|make'               => \$make);
  148.  
  149.   # Split the warnings as a list of elements instead of a list of
  150.   # lists.
  151.   @warning = map { split /,/ } @warning;
  152.   parse_WARNINGS;
  153.   parse_warnings '--warnings', @warning;
  154.  
  155.   # Even if the user specified a configure.ac, trim to get the
  156.   # directory, and look for configure.ac again.  Because (i) the code
  157.   # is simpler, and (ii) we are still able to diagnose simultaneous
  158.   # presence of configure.ac and configure.in.
  159.   @ARGV = map { /configure\.(ac|in)$/ ? dirname ($_) : $_ } @ARGV;
  160.   push @ARGV, '.' unless @ARGV;
  161.  
  162.   if ($verbose && $debug)
  163.     {
  164.       for my $prog ($autoconf, $autoheader,
  165.             $automake, $aclocal,
  166.             $autopoint,
  167.             $libtoolize)
  168.     {
  169.       xsystem ("$prog --version | sed 1q >&2");
  170.       print STDERR "\n";
  171.     }
  172.     }
  173.  
  174.   $aclocal_supports_force = `$aclocal --help` =~ /--force/;
  175.  
  176.   # Dispatch autoreconf's option to the tools.
  177.   # --include;
  178.   $autoconf   .= join (' --include=', '', @include);
  179.   $autoconf   .= join (' --prepend-include=', '', @prepend_include);
  180.   $autoheader .= join (' --include=', '', @include);
  181.   $autoheader .= join (' --prepend-include=', '', @prepend_include);
  182.  
  183.   # --install and --symlink;
  184.   if ($install)
  185.     {
  186.       $automake   .= ' --add-missing';
  187.       $automake   .= ' --copy' unless $symlink;
  188.       $libtoolize .= ' --copy' unless $symlink;
  189.     }
  190.   # --force;
  191.   if ($force)
  192.     {
  193.       $aclocal    .= ' --force'
  194.     if $aclocal_supports_force;
  195.       $autoconf   .= ' --force';
  196.       $autoheader .= ' --force';
  197.       $automake   .= ' --force-missing';
  198.       $autopoint  .= ' --force';
  199.       $libtoolize .= ' --force';
  200.     }
  201.   else
  202.     {
  203.       # The implementation of --no-force is bogus in all implementations
  204.       # of Automake up to 1.8, so we avoid it in these cases.  (Automake
  205.       # 1.8 is the first version where aclocal supports force, hence
  206.       # the condition.)
  207.       $automake .= ' --no-force'
  208.     if $aclocal_supports_force;
  209.     }
  210.   # --debug;
  211.   if ($debug)
  212.     {
  213.       $autoconf   .= ' --verbose --debug';
  214.       $autoheader .= ' --verbose --debug';
  215.       $automake   .= ' --verbose';
  216.       $aclocal    .= ' --verbose';
  217.       $libtoolize .= ' --debug';
  218.     }
  219.   # --warnings;
  220.   if (@warning)
  221.     {
  222.       my $warn = ' --warnings=' . join (',', @warning);
  223.       $autoconf   .= $warn;
  224.       $autoheader .= $warn;
  225.       $automake   .= $warn
  226.     if `$automake --help` =~ /--warnings/;
  227.     }
  228. }
  229.  
  230.  
  231. # &run_aclocal ($ACLOCAL, $FLAGS)
  232. # -------------------------------
  233. # Update aclocal.m4 as lazily as possible, as aclocal pre-1.8 always
  234. # overwrites aclocal.m4, hence triggers autoconf, autoheader, automake
  235. # etc. uselessly.  aclocal 1.8+ does not need this.
  236. sub run_aclocal ($$)
  237. {
  238.   my ($aclocal, $flags) = @_;
  239.  
  240.   # aclocal 1.8+ does all this for free.  It can be recognized by its
  241.   # --force support.
  242.   if ($aclocal_supports_force)
  243.     {
  244.       xsystem ("$aclocal $flags");
  245.     }
  246.   else
  247.     {
  248.       xsystem ("$aclocal $flags --output=aclocal.m4t");
  249.       # aclocal may produce no output.
  250.       if (-f 'aclocal.m4t')
  251.     {
  252.       update_file ('aclocal.m4t', 'aclocal.m4');
  253.       # Make sure that the local m4 files are older than
  254.       # aclocal.m4.
  255.       #
  256.       # Why is not always the case?  Because we already run
  257.       # aclocal at first (before tracing), which, for instance,
  258.       # can find Gettext's macros in .../share/aclocal, so we may
  259.       # have had the right aclocal.m4 already.  Then autopoint is
  260.       # run, and installs locally these M4 files.  Then
  261.       # autoreconf, via update_file, sees it is the _same_
  262.       # aclocal.m4, and doesn't change its timestamp.  But later,
  263.       # Automake's Makefile expresses that aclocal.m4 depends on
  264.       # these local files, which are newer, so it triggers aclocal
  265.       # again.
  266.       #
  267.       # To make sure aclocal.m4 is no older, we change the
  268.       # modification times of the local M4 files to be not newer
  269.       # than it.
  270.       #
  271.       # First, where are the local files?
  272.       my $aclocal_local_dir = '.';
  273.       if ($flags =~ /-I\s+(\S+)/)
  274.         {
  275.           $aclocal_local_dir = $1;
  276.         }
  277.       # All the local files newer than aclocal.m4 are to be
  278.       # made not newer than it.
  279.       my $aclocal_m4_mtime = mtime ('aclocal.m4');
  280.       for my $file (glob ("$aclocal_local_dir/*.m4"), 'acinclude.m4')
  281.         {
  282.           if ($aclocal_m4_mtime < mtime ($file))
  283.         {
  284.           debug "aging $file to be not newer than aclocal.m4";
  285.           utime $aclocal_m4_mtime, $aclocal_m4_mtime, $file;
  286.         }
  287.         }
  288.     }
  289.     }
  290. }
  291.  
  292. # &autoreconf_current_directory
  293. # -----------------------------
  294. sub autoreconf_current_directory ()
  295. {
  296.   my $configure_ac = require_configure_ac;
  297.  
  298.   # ---------------------- #
  299.   # Is it using Autoconf?  #
  300.   # ---------------------- #
  301.  
  302.   my $uses_autoconf;
  303.   my $uses_gettext;
  304.   my $configure_ac_file = new Autom4te::XFile $configure_ac;
  305.   while ($_ = $configure_ac_file->getline)
  306.      {
  307.        s/#.*//;
  308.        s/dnl.*//;
  309.        $uses_autoconf = 1 if /AC_INIT/;
  310.        # See below for why we look for gettext here.
  311.        $uses_gettext = 1  if /^AM_GNU_GETTEXT_VERSION/;
  312.      }
  313.  
  314.   if (!$uses_autoconf)
  315.     {
  316.       verb "$configure_ac: not using Autoconf";
  317.       return;
  318.     }
  319.  
  320.  
  321.   # ------------------- #
  322.   # Running autopoint.  #
  323.   # ------------------- #
  324.  
  325.   # Gettext is a bit of a problem: its macros are not necessarily
  326.   # visible to aclocal, so if we start with a completely striped down
  327.   # package (think of a fresh CVS checkout), running `aclocal' first
  328.   # will fail: the Gettext macros are missing.
  329.   #
  330.   # Therefore, we can't use the traces to decide if we use Gettext or
  331.   # not.  I guess that once Gettext move to 2.5x we will be able to,
  332.   # but in the meanwhile forget it.
  333.   #
  334.   # We can only grep for AM_GNU_GETTEXT_VERSION in configure.ac.  You
  335.   # might think this approach is naive, and indeed it is, as it
  336.   # prevents one to embed AM_GNU_GETTEXT_VERSION in another *.m4, but
  337.   # anyway we don't limit the generality, since... that's what
  338.   # autopoint does.  Actually, it is even more restrictive, as it
  339.   # greps for `^AM_GNU_GETTEXT_VERSION('.  We did this above, while
  340.   # scanning configure.ac.
  341.   if (!$uses_gettext)
  342.     {
  343.       verb "$configure_ac: not using Gettext";
  344.     }
  345.   elsif (!$install)
  346.     {
  347.       verb "$configure_ac: not running autopoint: --install not given";
  348.     }
  349.   else
  350.     {
  351.       xsystem "$autopoint";
  352.     }
  353.  
  354.  
  355.   # ----------------- #
  356.   # Running aclocal.  #
  357.   # ----------------- #
  358.  
  359.   # Run it first: it might discover new macros to add, e.g.,
  360.   # AC_PROG_LIBTOOL, which we will trace later to see if Libtool is
  361.   # used.
  362.   #
  363.   # Always run it.  Tracking its sources for up-to-dateness is too
  364.   # complex and too error prone.  The best we can do is avoiding
  365.   # nuking the time stamp.
  366.   my $uses_aclocal = 1;
  367.  
  368.   # Nevertheless, if aclocal.m4 exists and is not made by aclocal,
  369.   # don't run aclocal.
  370.  
  371.   if (-f 'aclocal.m4')
  372.     {
  373.       my $aclocal_m4 = new Autom4te::XFile 'aclocal.m4';
  374.       $_ = $aclocal_m4->getline;
  375.       $uses_aclocal = 0
  376.     unless defined ($_) && /generated.*by aclocal/;
  377.     }
  378.  
  379.   # If there are flags for aclocal in Makefile.am, use them.
  380.   my $aclocal_flags = '';
  381.   if ($uses_aclocal && -f 'Makefile.am')
  382.     {
  383.       my $makefile = new Autom4te::XFile 'Makefile.am';
  384.       while ($_ = $makefile->getline)
  385.     {
  386.       if (/^ACLOCAL_[A-Z_]*FLAGS\s*=\s*(.*)/)
  387.         {
  388.           $aclocal_flags = $1;
  389.           last;
  390.         }
  391.     }
  392.     }
  393.  
  394.   if (!$uses_aclocal)
  395.     {
  396.       verb "$configure_ac: not using aclocal";
  397.     }
  398.   else
  399.     {
  400.       # Some filesystems have sub-second time stamps, and if so we may
  401.       # run into trouble later, after we rerun autoconf and set the
  402.       # time stamps of input files to be no greater than aclocal.m4,
  403.       # because the time-stamp-setting operation (utime) has a
  404.       # resolution of only 1 second.  Work around the problem by
  405.       # ensuring that there is at least a one-second window before the
  406.       # time stamp of aclocal.m4t in which no file time stamps can
  407.       # fall.
  408.       sleep 1;
  409.  
  410.       run_aclocal ($aclocal, $aclocal_flags);
  411.     }
  412.  
  413.   # We might have to rerun aclocal if Libtool (or others) imports new
  414.   # macros.
  415.   my $rerun_aclocal = 0;
  416.  
  417.  
  418.  
  419.   # ------------------------------- #
  420.   # See what tools will be needed.  #
  421.   # ------------------------------- #
  422.  
  423.   # Perform a single trace reading to avoid --force forcing a rerun
  424.   # between two --trace, that's useless.  If there is no AC_INIT, then
  425.   # we are not interested: it looks like a Cygnus thingy.
  426.   my $aux_dir;
  427.   my $uses_gettext_via_traces;
  428.   my $uses_libtool;
  429.   my $uses_autoheader;
  430.   my @subdir;
  431.   verb "$configure_ac: tracing";
  432.   my $traces = new Autom4te::XFile
  433.     ("$autoconf"
  434.      . join (' --trace=', '',
  435.          # If you change this list, update the
  436.          # `Autoreconf-preselections' section of autom4te.in.
  437.          'AC_CONFIG_AUX_DIR:AC_CONFIG_AUX_DIR:\$1',
  438.          'AC_CONFIG_HEADERS',
  439.          'AC_CONFIG_SUBDIRS:AC_CONFIG_SUBDIRS:\$1',
  440.          'AC_INIT',
  441.          'AC_PROG_LIBTOOL',
  442.          'AM_GNU_GETTEXT',
  443.         )
  444.      . ' |');
  445.   while ($_ = $traces->getline)
  446.     {
  447.       $aux_dir = $1                 if /AC_CONFIG_AUX_DIR:(.*)/;
  448.       $uses_autoconf = 1            if /AC_INIT/;
  449.       $uses_gettext_via_traces = 1  if /AM_GNU_GETTEXT/;
  450.       $uses_libtool = 1             if /AC_PROG_LIBTOOL/;
  451.       $uses_autoheader = 1          if /AC_CONFIG_HEADERS/;
  452.       push @subdir, split (' ', $1) if /AC_CONFIG_SUBDIRS:(.*)/;
  453.     }
  454.  
  455.   # The subdirs are *optional*, they may not exist.
  456.   foreach (@subdir)
  457.     {
  458.       if (-d)
  459.     {
  460.       verb "$configure_ac: subdirectory $_ to autoreconf";
  461.       autoreconf ($_);
  462.     }
  463.       else
  464.     {
  465.       verb "$configure_ac: subdirectory $_ not present";
  466.     }
  467.     }
  468.  
  469.   # Gettext consistency checks...
  470.   error "$configure_ac: AM_GNU_GETTEXT is used, but not AM_GNU_GETTEXT_VERSION"
  471.     if $uses_gettext_via_traces && ! $uses_gettext;
  472.   error "$configure_ac: AM_GNU_GETTEXT_VERSION is used, but not AM_GNU_GETTEXT"
  473.     if $uses_gettext && ! $uses_gettext_via_traces;
  474.  
  475.  
  476.   # ---------------------------- #
  477.   # Setting up the source tree.  #
  478.   # ---------------------------- #
  479.  
  480.   # libtoolize, automake --add-missing etc. will drop files in the
  481.   # $AUX_DIR.  But these tools fail to install these files if the
  482.   # directory itself does not exist, which valid: just imagine a CVS
  483.   # repository with hand written code only (there is not even a need
  484.   # for a Makefile.am!).
  485.  
  486.   if (defined $aux_dir && ! -d $aux_dir)
  487.     {
  488.       verb "$configure_ac: creating directory $aux_dir";
  489.       mkdir $aux_dir
  490.     or error "cannot create $aux_dir: $!";
  491.     }
  492.  
  493.  
  494.   # -------------------- #
  495.   # Running libtoolize.  #
  496.   # -------------------- #
  497.  
  498.   if (!$uses_libtool)
  499.     {
  500.       verb "$configure_ac: not using Libtool";
  501.     }
  502.   elsif ($install)
  503.     {
  504.       xsystem ($libtoolize);
  505.       $rerun_aclocal = 1;
  506.     }
  507.   else
  508.     {
  509.       verb "$configure_ac: not running libtoolize: --install not given";
  510.     }
  511.  
  512.  
  513.  
  514.   # ------------------- #
  515.   # Rerunning aclocal.  #
  516.   # ------------------- #
  517.  
  518.   # If we re-installed Libtool or Gettext, the macros might have changed.
  519.   # Automake also needs an up-to-date aclocal.m4.
  520.   if ($rerun_aclocal)
  521.     {
  522.       if (!$uses_aclocal)
  523.     {
  524.       verb "$configure_ac: not using aclocal";
  525.     }
  526.       else
  527.     {
  528.       run_aclocal ($aclocal, $aclocal_flags);
  529.     }
  530.     }
  531.  
  532.  
  533.   # ------------------ #
  534.   # Running autoconf.  #
  535.   # ------------------ #
  536.  
  537.   # Don't try to be smarter than `autoconf', which does its own up to
  538.   # date checks.
  539.   #
  540.   # We prefer running autoconf before autoheader, because (i) the
  541.   # latter runs the former, and (ii) autoconf is stricter than
  542.   # autoheader.  So all in all, autoconf should give better error
  543.   # messages.
  544.   xsystem ($autoconf);
  545.  
  546.  
  547.   # -------------------- #
  548.   # Running autoheader.  #
  549.   # -------------------- #
  550.  
  551.   # We now consider that if AC_CONFIG_HEADERS is used, then autoheader
  552.   # is used too.
  553.   #
  554.   # Just as for autoconf, up to date ness is performed by the tool
  555.   # itself.
  556.   #
  557.   # Run it before automake, since the latter checks the presence of
  558.   # config.h.in when it sees an AC_CONFIG_HEADERS.
  559.   if (!$uses_autoheader)
  560.     {
  561.       verb "$configure_ac: not using Autoheader";
  562.     }
  563.   else
  564.     {
  565.       xsystem ($autoheader);
  566.     }
  567.  
  568.  
  569.   # ------------------ #
  570.   # Running automake.  #
  571.   # ------------------ #
  572.  
  573.   # Assumes that there is a Makefile.am in the topmost directory.
  574.   if (!-f 'Makefile.am')
  575.     {
  576.       verb "$configure_ac: not using Automake";
  577.     }
  578.   else
  579.     {
  580.       # We should always run automake, and let it decide whether it shall
  581.       # update the file or not.  In fact, the effect of `$force' is already
  582.       # included in `$automake' via `--no-force'.
  583.       xsystem ($automake);
  584.     }
  585.  
  586.  
  587.   # -------------- #
  588.   # Running make.  #
  589.   # -------------- #
  590.  
  591.   if ($make)
  592.     {
  593.       if (!-f "config.status")
  594.     {
  595.       verb "no config.status: cannot re-make";
  596.     }
  597.       else
  598.     {
  599.       xsystem ("./config.status --recheck");
  600.       xsystem ("./config.status");
  601.       if (!-f "Makefile")
  602.         {
  603.           verb "no Makefile: cannot re-make";
  604.         }
  605.       else
  606.         {
  607.           xsystem ("make");
  608.         }
  609.     }
  610.     }
  611. }
  612.  
  613.  
  614. # &autoreconf ($DIRECTORY)
  615. # ------------------------
  616. # Reconf the $DIRECTORY.
  617. sub autoreconf ($)
  618. {
  619.   my ($directory) = @_;
  620.   my $cwd = cwd;
  621.  
  622.   # The format for this message is not free: taken from Emacs, itself
  623.   # using GNU Make's format.
  624.   verb "Entering directory `$directory'";
  625.   chdir $directory
  626.     or error "cannot chdir to $directory: $!";
  627.  
  628.   autoreconf_current_directory;
  629.  
  630.   # The format is not free: taken from Emacs, itself using GNU Make's
  631.   # format.
  632.   verb "Leaving directory `$directory'";
  633.   chdir $cwd
  634.     or error "cannot chdir to $cwd: $!";
  635. }
  636.  
  637.  
  638. ## ------ ##
  639. ## Main.  ##
  640. ## ------ ##
  641.  
  642. # When debugging, it is convenient that all the related temporary
  643. # files be at the same place.
  644. mktmpdir ('ar');
  645. $ENV{'TMPDIR'} = $tmp;
  646. parse_args;
  647.  
  648. # Autoreconf all the given configure.ac.  A while loop, not a for,
  649. # since the list can change at runtime because of AC_CONFIG_SUBDIRS.
  650. for my $directory (@ARGV)
  651.   {
  652.     autoreconf ($directory);
  653.   }
  654.  
  655. ### Setup "GNU" style for perl-mode and cperl-mode.
  656. ## Local Variables:
  657. ## perl-indent-level: 2
  658. ## perl-continued-statement-offset: 2
  659. ## perl-continued-brace-offset: 0
  660. ## perl-brace-offset: 0
  661. ## perl-brace-imaginary-offset: 0
  662. ## perl-label-offset: -2
  663. ## cperl-indent-level: 2
  664. ## cperl-brace-offset: 0
  665. ## cperl-continued-brace-offset: 0
  666. ## cperl-label-offset: -2
  667. ## cperl-extra-newline-before-brace: t
  668. ## cperl-merge-trailing-else: nil
  669. ## cperl-continued-statement-offset: 2
  670. ## End:
  671.